//Description:
// an exploration of the integration of
// coloring and transforming

//Author: Ben Scheele
//Date: primary 6-9-01, secondary 11-2-02, 
//tertiary 11-13-02, finally 1-8-03 

#declare rad = 1;

global_settings{
  
#if(rad = true)
  radiosity{
    pretrace_start 0.08
    pretrace_end .01
    count 100

    nearest_count 7
    error_bound 1.5
    recursion_limit 2

    low_error_factor 0.5
    gray_threshold 0.0
    minimum_reuse 0.015
    brightness .5

    adc_bailout 0.01/2
  }
  ambient_light off
   #end

}              

camera{
  location 28.5*4*y
  look_at 0
  angle 40/4
}

light_source{ <50,300,20> rgb .5 }                    
               
#declare a = 1;               
#declare b = .6;
#declare c = .1;

sky_sphere{
  pigment{ 
    gradient z triangle_wave 
    color_map{ [ 0 rgb <.6,.6,.8>*a ]
               [ .5 rgb <.5,.5,.65>*b ]
               [ 1 rgb <.4,.4,.5>*c ] 
    }
    phase .5 frequency 1
  }
}


#declare fin =
finish{ ambient .2 diffuse .8 phong .4 reflection .2 metallic .3 
       specular.2 roughness .02 }

#declare met_fin =
   
finish {
  specular 0.5
  roughness .001
  brilliance 1
  phong .5
  phong_size 15
  metallic .5
  diffuse .6
  ambient 0
  reflection {
    0.2, .4  
    falloff 2
    metallic .5
    fresnel on   
  }
  conserve_energy
}  


#declare r1 = seed(16748);
#declare s = .35;
#declare Step = .75;
#declare X = 0;
#declare EndX = 42;

#while(X < EndX)
  #declare Z = 0;
  #declare EndZ = 40;
  #while(Z < EndZ) 
    #declare R = sqrt(X*X+Z*Z);
  
   cone{ 0 , 0, x, .5
      pigment{ rgbf<1+sin(.3*R),.3,1-sin(.3*R)>+.3*rand(r1) }
    
    scale .3*pow(X,.75)+.001
    rotate 5*X*z
    translate pow(X,.75)*x    
    
    normal{ bumps .025 scale .001 }

    rotate X*y*4 
    rotate Z*360/(EndZ + Step)*y
    scale .05*pow(X,.75)+.001
    
    interior{
      ior 1.5  
    }
                  
    finish{ met_fin }
   }
    
  #declare Z = Z + Step;
  #end
#declare X = X + Step;
#end