//Description:
//  redesign of the gold rod spiral scene
//  added color change, tweaked transformations
//  added water to the vanishing point, with scattering media

//Author: Ben Scheele
//Date: 1-4-2003


#declare rad = 0;

global_settings{
  
#if(rad = true)
  radiosity{
    pretrace_start 0.08
    pretrace_end .01
    count 80

    nearest_count 5
    error_bound 1.5
    recursion_limit 1

    low_error_factor 0.65
    gray_threshold 0.0
    minimum_reuse 0.015
    brightness 1

    adc_bailout 0.01/2
  }
  ambient_light off #end

}              

camera {
  location <0,5,-75>
  up y
  right x
  look_at 5*y
   angle 60
}

light_source { <200,-1000,-2000> rgb .4 }
light_source { <-2,1,-5>*1000 rgb .4 }
light_source { 150*z rgb 1 }

background {rgb 1}

//the water plane -----------------------   

plane{ z, 55
pigment{ color rgbf <1, 1.1, 1.3, .5> transmit .5 } 
finish{ phong .1 phong_size 90 diffuse .8 ambient 0 reflection{ .2 .4 fresnel on }
} 

normal{ ripples scale 1000 frequency 500 }

interior{ 
  ior 1.33
  fade_distance .5
  fade_power 2
  fade_color rgb <.2,.4,.9>*1.3
  caustics 1.5

  media{        
   scattering{ 1 <.9,.5,.05>*.0075 extinction .5 } 
   emission rgb <.9,.3,.8>*.003
   absorption <.9,.3,.8>*.003 
   samples 2, 2
  }
}
hollow
} 

plane { z, 300 pigment{ rgb<.7,.9,2>*.8 } finish{ ambient .05 brilliance .8 } hollow }

// -------------------------------------

// rods -----------------------------------

#declare r1 = seed(50);
#declare r2 = seed(60);
#declare r3 = seed(70);

#declare Rod_Fin =

  finish { 
    ambient .2
    specular 0.5
    roughness 0.01
    brilliance .5
    metallic
    phong .65 phong_size 100
    diffuse .8
    reflection {
      0.15, 0.5   
      falloff 1.5
      metallic   
    }
    conserve_energy
  } 

   #declare Step = .0425;//.005;
   #declare X = 0;
   #declare EndX= 69;
   #while (X < EndX + Step)
  
   cone{-6*z 1.5-.5*X/EndX 120*z .5 
   
     translate X*x
     scale <1,1,2*rand(r1)+.0025*pow(X,1.05)+.001>
     scale sin(X/30-X/40*rand(r3))+.01
     rotate 1.5*pow(X,1.5)*z
   
   pigment{ rgb <1-X/EndX,0,X/EndX> }
   finish{ Rod_Fin } 
   
     normal{ bumps .06 scale .03 } 
   }       
          
   #declare X = X + Step;
   #end